Below is the file 'configure.ac' from this revision. You can also download the file.

AC_INIT(monotone-viz, 0.9)

AC_PROG_OCAML
AC_PROG_OCAML_TOOLS
AC_PROG_CAMLP4
if test -z "$CAMLP4O" ; then
  AC_MSG_ERROR([

Could not find camlp4o. Camlp4 is required to build monotone-viz.])
fi

# Check LablGTK
AC_ARG_WITH([lablgtk-dir],
	    AS_HELP_STRING([--with-lablgtk-dir],
			   [specify location of lablgtk library]),
	    LABLGTK_DIR=$withval)
AC_CHECK_OCAML_MODULE(lablgtk, LABLGTK_DIR, GFile, +lablgtk2 +lablgtk)
# Stop if LablGTK is not found
if test -z "$LABLGTK_DIR" ; then
  AC_MSG_ERROR([

Could not find LablGTK. Make sure LablGTK >= 2.4.0 is installed and
specify its location to configure with the `--with-lablgtk-dir'
option.])
fi
LABLGTK_DIR=$(echo $LABLGTK_DIR | sed "s@^+@$OCAMLLIB/@")
# Check if LablGTK was compiled with libgnomecanvas support
AC_MSG_CHECKING([GnomeCanvas support])
if test -r "$LABLGTK_DIR/lablgnomecanvas.cma" ; then
  AC_MSG_RESULT(found)
else
  AC_MSG_ERROR([

libgnomecanvas support not found.
LablGTK need to be built with GnomeCanvas support.])
fi
# Check if LablGTK is natively compiled
if test -r "$LABLGTK_DIR/lablgtk.cmxa" -a -r "$LABLGTK_DIR/lablgnomecanvas.cmxa"; then
  echo [Using the native code compiler]
else
  echo [Using the byte code compiler]
  OCAMLBEST=byte
fi

AC_OUTPUT(config.make)